Zusammenführen mehrerer Excel-Dateien in eine Datei

Haben Sie viele Excel-Dateien und möchten diese zu einer einzigen zusammenführen?

Vielleicht möchten Sie mehrere Tagesberichte in einer monatlichen Berichtsdatei zusammenfassen. Oder Sie möchten die Verkaufsberichte für jedes Gebiet in einer Berichtsdatei zusammenfassen.

Es gibt viele Möglichkeiten, mehrere Excel-Dateien zu einer einzigen Datei zusammenzuführen. Wenn Sie nur wenige Dateien zusammenführen möchten, können Sie dies manuell tun. Sie können dies tun, indem Sie den Inhalt des Dokuments „Copy & Paste“, „Move or Copy“ Blätter, usw.

Wenn Sie viele Dateien zusammenführen wollen, ist der schnellste Weg die Verwendung von VBA-Makros.

Zusammenführen mehrerer Excel-Dateien in eine einzige

Erstellen Sie eine neue Excel-Datei.
Drücken Sie ( Alt + F11 ), um den Visual Basic Editor zu öffnen.
Nachdem das Visual Basic Editor-Fenster geöffnet wurde, klicken Sie auf “ ThisWorkbook > Insert > Module ”.

Kopieren Sie dann das folgende Makro-Skript

Sub MergeExcelFiles()
    Dim fnameList, fnameCurFile As Variant
    Dim countFiles, countSheets As Integer
    Dim wksCurSheet As Worksheet
    Dim wbkCurBook, wbkSrcBook As Workbook
 
    fnameList = Application.GetOpenFilename(FileFilter:="Microsoft Excel Workbooks (*.xls;*.xlsx;*.xlsm),*.xls;*.xlsx;*.xlsm", Title:="Choose Excel files to merge", MultiSelect:=True)
 
    If (vbBoolean <> VarType(fnameList)) Then
 
        If (UBound(fnameList) > 0) Then
            countFiles = 0
            countSheets = 0
 
            Application.ScreenUpdating = False
            Application.Calculation = xlCalculationManual
 
            Set wbkCurBook = ActiveWorkbook
 
            For Each fnameCurFile In fnameList
                countFiles = countFiles + 1
 
                Set wbkSrcBook = Workbooks.Open(Filename:=fnameCurFile)
 
                For Each wksCurSheet In wbkSrcBook.Sheets
                    countSheets = countSheets + 1
                    wksCurSheet.Copy after:=wbkCurBook.Sheets(wbkCurBook.Sheets.Count)
                Next
 
                wbkSrcBook.Close SaveChanges:=False
 
            Next
 
            Application.ScreenUpdating = True
            Application.Calculation = xlCalculationAutomatic
 
            MsgBox "Processed " & countFiles & " files" & vbCrLf & "Merged " & countSheets & " worksheets", Title:="Merge Excel files"
        End If
 
    Else
        MsgBox "No files selected", Title:="Merge Excel files"
    End If
End Sub

Quelle: ablebits.com