Measuring Command Execution Time with Windows command line

30 May 2022

Home » Blogs » Windows » Measuring Command Execution Time with Windows command line

In this article, Bardimin will share a script that you can use to calculate the time it takes for an or command to complete .

The method is quite easy, copy the following script to notepad and save it with the name ” ExecutionTime.bat “.

@echo off

set start=%time%

:: Runs your command
cmd /c %*

set end=%time%
set options="tokens=1-4 delims=:.,"
for /f %options% %%a in ("%start%") do set start_h=%%a&set /a start_m=100%%b %% 100&set /a start_s=100%%c %% 100&set /a start_ms=100%%d %% 100
for /f %options% %%a in ("%end%") do set end_h=%%a&set /a end_m=100%%b %% 100&set /a end_s=100%%c %% 100&set /a end_ms=100%%d %% 100

set /a hours=%end_h%-%start_h%
set /a mins=%end_m%-%start_m%
set /a secs=%end_s%-%start_s%
set /a ms=%end_ms%-%start_ms%
if %ms% lss 0 set /a secs = %secs% - 1 & set /a ms = 100%ms%
if %secs% lss 0 set /a mins = %mins% - 1 & set /a secs = 60%secs%
if %mins% lss 0 set /a hours = %hours% - 1 & set /a mins = 60%mins%
if %hours% lss 0 set /a hours = 24%hours%
if 1%ms% lss 100 set ms=0%ms%

:: Mission accomplished
set /a totalsecs = %hours%*3600 + %mins%*60 + %secs%
echo Execution time %hours%:%mins%:%secs%.%ms% (%totalsecs%.%ms%s total)

How to use

You can use the script from with the command

ExecutionTime [your command]

For example, you want to calculate the required by the file ” myscript.bat ” you can use the following command

ExecutionTime myscript.bat

And if you want to count the length of time you use . You can type as follows

ExecutionTime "C:\Program Files ( x86)\ Microsoft Office\root\ Office16\WINWORD.EXE"
TOP TUTORIALS:  Easy Ways to Create Desktop Shortcuts for Favorite Website Pages


Submit a Comment