More

    Mesurer le temps d’exécution des commandes avec la ligne de commande Windows

    Dans cet article, Bardimin partagera un script que vous pouvez utiliser pour calculer le temps qu’il faut pour qu’une application ou une commande se termine.

    La méthode est assez simple, copiez le script suivant dans le bloc-notes et enregistrez-le sous le nom  » ExecutionTime.bat « .

    @echo off
@setlocal

set start=%time%

:: Runs your command
cmd /c %*

set end=%time%
set options="tokens=1-4 delims=:.,"
for /f %options% %%a in ("%start%") do set start_h=%%a&set /a start_m=100%%b %% 100&set /a start_s=100%%c %% 100&set /a start_ms=100%%d %% 100
for /f %options% %%a in ("%end%") do set end_h=%%a&set /a end_m=100%%b %% 100&set /a end_s=100%%c %% 100&set /a end_ms=100%%d %% 100

set /a hours=%end_h%-%start_h%
set /a mins=%end_m%-%start_m%
set /a secs=%end_s%-%start_s%
set /a ms=%end_ms%-%start_ms%
if %ms% lss 0 set /a secs = %secs% - 1 & set /a ms = 100%ms%
if %secs% lss 0 set /a mins = %mins% - 1 & set /a secs = 60%secs%
if %mins% lss 0 set /a hours = %hours% - 1 & set /a mins = 60%mins%
if %hours% lss 0 set /a hours = 24%hours%
if 1%ms% lss 100 set ms=0%ms%

:: Mission accomplished
set /a totalsecs = %hours%*3600 + %mins%*60 + %secs%
echo Execution time %hours%:%mins%:%secs%.%ms% (%totalsecs%.%ms%s total)

    Comment l’utiliser

    Vous pouvez utiliser le script à partir de CMD avec la commande

    ExecutionTime [your command]

    Par exemple, vous souhaitez calculer le temps d’exécution du fichier  » myscript.bat « , vous pouvez utiliser la commande suivante

    ExecutionTime myscript.bat

    Et si vous voulez compter la durée d’utilisation de Microsoft Word. Vous pouvez taper comme suit

    ExecutionTime "C:\Program Files ( x86)\ Microsoft Office\root\ Office16\WINWORD.EXE"

    Dernières articles

    Articles Connexes